Join of two non intersecting conic curves in P4:

R=QQ[x0,x1,x2,x3,x4,y0,y1,y2,y3,y4,z0,z1,z2,z3,z4,s,t]

Ix=ideal(x0,x1,x2^2-x3*x4)
Iy=ideal(y3,y4,y2^2-y0*y1)
Iz=ideal(z0-s*x0-t*y0,z1-s*x1-t*y1,z2-s*x2-t*y2,z3-s*x3-t*y3,z4-s*x4-t*y4) 

I=saturate(Ix+Iy+Iz,ideal(s,t)) -- saturate w.r.t. ideal(s,t) to have [s:t] in P1

Join=eliminate({x0,x1,x2,x3,x4,y0,y1,y2,y3,y4,s,t},I)

---------

Secant variety to a rational normal curve in P4:

A=QQ[s,t];
B=QQ[z0,z1,z2,z3,z4];
L={s^4,s^3*t,s^2*t^2,s*t^3,t^4};
f=map(A,B,L);

C=kernel f;

--Output: ideal(z3^2-z2*z4, z2*z3-z1*z4, z1*z3-z0*z4, z2^2-z0*z4, z1*z2-z0*z3,z1^2-z0*z2);

R=QQ[x0,x1,x2,x3,x4,y0,y1,y2,y3,y4,z0,z1,z2,z3,z4,s,t];

Ix=ideal(x3^2-x2*x4, x2*x3-x1*x4, x1*x3-x0*x4, x2^2-x0*x4, x1*x2-x0*x3,x1^2-x0*x2);
Iy=ideal(y3^2-y2*y4, y2*y3-y1*y4, y1*y3-y0*y4, y2^2-y0*y4, y1*y2-y0*y3,y1^2-y0*y2);
Iz=ideal(z0-s*x0-t*y0,z1-s*x1-t*y1,z2-s*x2-t*y2,z3-s*x3-t*y3,z4-s*x4-t*y4); 

I=saturate(Ix+Iy+Iz, ideal(s,t)); -- saturate wrt (s,t) to have [s:t] in P1

Secant=eliminate({x0,x1,x2,x3,x4,y0,y1,y2,y3,y4,s,t},I);

-- Output: ideal(z2^3-2*z1*z2*z3+z0*z3^2+z1^2*z4-z0*z2*z4)

---------

Tangential variety to the twisted cubic curve in P3

A=QQ[s,t];
B=QQ[p0,p1,p2,p3];
L={s^3,s^2*t,s*t^2,t^3};
f=map(A,B,L);

C= kernel f;

R=QQ[x,y,z,w,p0,p1,p2,p3];
Ip=ideal(p2^2-p1*p3, p1*p2-p0*p3, p1^2-p0*p2);
I=ideal(p3*(x-p0)-p2*(y-p1)-p1*(z-p2)+p0*(w-p3),-p2*(x-p0)+2*p1*(y-p1)-p0*(z-p3),p3*(y-p1)-2*p2*(z-p2)+p1*(w-p3));
J=saturate(I+Ip,ideal(p0,p1,p2,p3))
eliminate({p0,p1,p2,p3},J)